In the paper there are two ways to calculate K and S
1) using 3x3 solution and Proposition 2.2
2) as eigenvalues of lower 2x2 block of G tensor in Fermi coordinates

In this notebook we show that these two methods coincide.

Define 3x3 solution

P = {{0, 0, 0}, {0, 1, 0}, {0, 0, 1}};

Gr = {{b11, b12, b13}, {b12, b22, b23}, {b13, b23, 
            b33}};
Gi = {{a11, a12, a13}, {a12, a22, a23}, {a13, a23, 
            a33}};
G0 = Gr +  I Gi;
G0  //  MatrixForm

G[t_] :=  G0 . Inverse[IdentityMatrix[3]  +  P . G0 t]

FullSimplify[D[G[t], t] + G[t] . P . G[t]]

Greal[t_] :=  ComplexExpand[Re[G[t]]]

Define K and S using Proposition 2.2 which gives these
as a function of the 3x3 solution

(* 
      return adjugate of symmetric matrix *) 
Adj[
        mat_] := {{-(A23^2) + A22 A33, 
            A13 A23 - A12 A33, -A13 A22 + A12 A23}, {A13 A23 - 
              A12 A33, -(A13^2) + A11 A33, 
            A12 A13 - A11 A23}, {-A13 A22 + A12 A23, 
            A12 A13 - A11 A23, -(A12^2) + 
              A11 A22}} /. {A11 ->  mat[[1]][[1]],  
A12 -> mat[[1]][[2]],  
          A13 ->  mat[[1]][[3]],  
          A23 ->  mat[[2]][[3]],  
          A22 -> mat[[2]][[2]],  
          A33 -> mat[[3]][[3]]}

 (* check *) 

    Mrand = 
        Table[Random[Real], {i, 1, 3}, {j, 1, 3}] ;

    Mrand  =  1/2 (Mrand + Transpose[Mrand]) ;   (* 
      make Mrand symmetric *) 
Mrand  //  
      MatrixForm

     Norm[Adj[Mrand] - Det[Mrand] Inverse[Mrand]]

p = {1, 0, 0};
K3[t_] := p . Adj[Greal[t]] .  p
S3[t_] := -1/2 
         p . (Greal[t] - Tr[Greal[t]] IdentityMatrix[3]) .  
          p

Define K and S using 2x2 shape operator

Gsc[
        t_] := {{G[t][[2]][[2]], G[
                t][[2]][[3]]}, 
{G[
                t][[3]][[2]], G[
                t][[3]][[3]]}}

FullSimplify[D[Gsc[t], t] + Gsc[t] . Gsc[t]]

GscReal[t_] :=  ComplexExpand[Re[Gsc[t]]]

K2[t_] := FullSimplify[Det[GscReal[t]]]
S2[t_] := 1/2 FullSimplify[Tr[GscReal[t]]]

K2[t]

S2[t]

Check that different expressions coincide:

FullSimplify[K3[t] - K2[t]]

FullSimplify[S3[t] - S2[t]]

Done!